69c9cd277d
This is a CodeExtractor improvement which adds support for extracting blocks which have exception handling constructs if that is legal to do. CodeExtractor performs validation checks to ensure that extraction is legal when it finds invoke instructions or EH pads (landingpad, catchswitch, or cleanuppad) in blocks to be extracted. I have also added an option to allow extraction of blocks with alloca instructions, but no validation is done for allocas. CodeExtractor caller has to validate it himself before allowing alloca instructions to be extracted. By default allocas are still not allowed in extraction blocks. Differential Revision: https://reviews.llvm.org/D45904 llvm-svn: 332151
53 lines
1.3 KiB
LLVM
53 lines
1.3 KiB
LLVM
; RUN: opt < %s -skip-partial-inlining-cost-analysis -partial-inliner -S | FileCheck %s
|
|
; RUN: opt < %s -skip-partial-inlining-cost-analysis -passes=partial-inliner -S | FileCheck %s
|
|
|
|
declare void @bar()
|
|
declare i32 @__gxx_personality_v0(...)
|
|
declare i8* @__cxa_begin_catch(i8*)
|
|
declare void @__cxa_end_catch()
|
|
|
|
define internal void @callee(i1 %cond) personality i8* bitcast (i32 (...)* @__gxx_personality_v0 to i8*) {
|
|
entry:
|
|
br i1 %cond, label %if.then, label %if.end
|
|
|
|
if.then:
|
|
invoke void @bar()
|
|
to label %invoke.cont unwind label %lpad
|
|
|
|
invoke.cont:
|
|
br label %try.cont
|
|
|
|
lpad:
|
|
%0 = landingpad { i8*, i32 }
|
|
catch i8* null
|
|
%1 = extractvalue { i8*, i32 } %0, 0
|
|
%2 = extractvalue { i8*, i32 } %0, 1
|
|
br label %catch
|
|
|
|
catch:
|
|
%3 = call i8* @__cxa_begin_catch(i8* %1)
|
|
call void @__cxa_end_catch()
|
|
br label %try.cont
|
|
|
|
try.cont:
|
|
br label %if.end
|
|
|
|
if.end:
|
|
ret void
|
|
}
|
|
|
|
define internal void @caller(i1 %cond) {
|
|
; CHECK-LABEL: define {{.*}} @caller
|
|
entry:
|
|
; CHECK: entry:
|
|
; CHECK-NEXT: br i1
|
|
; CHECK: codeRepl.i:
|
|
; CHECK-NEXT: call void @callee.1_{{.*}}()
|
|
call void @callee(i1 %cond)
|
|
ret void
|
|
}
|
|
|
|
; CHECK-LABEL: define {{.*}} @callee.1_{{.*}}() personality i8* bitcast (i32 (...)* @__gxx_personality_v0 to i8*)
|
|
; CHECK: invoke void @bar()
|
|
; CHECK: landingpad
|