1e68724d24
Summary: This is a resurrection of work first proposed and discussed in Aug 2015: http://lists.llvm.org/pipermail/llvm-dev/2015-August/089384.html and initially landed (but then backed out) in Nov 2015: http://lists.llvm.org/pipermail/llvm-commits/Week-of-Mon-20151109/312083.html The @llvm.memcpy/memmove/memset intrinsics currently have an explicit argument which is required to be a constant integer. It represents the alignment of the dest (and source), and so must be the minimum of the actual alignment of the two. This change is the first in a series that allows source and dest to each have their own alignments by using the alignment attribute on their arguments. In this change we: 1) Remove the alignment argument. 2) Add alignment attributes to the source & dest arguments. We, temporarily, require that the alignments for source & dest be equal. For example, code which used to read: call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dest, i8* %src, i32 100, i32 4, i1 false) will now read call void @llvm.memcpy.p0i8.p0i8.i32(i8* align 4 %dest, i8* align 4 %src, i32 100, i1 false) Downstream users may have to update their lit tests that check for @llvm.memcpy/memmove/memset call/declaration patterns. The following extended sed script may help with updating the majority of your tests, but it does not catch all possible patterns so some manual checking and updating will be required. s~declare void @llvm\.mem(set|cpy|move)\.p([^(]*)\((.*), i32, i1\)~declare void @llvm.mem\1.p\2(\3, i1)~g s~call void @llvm\.memset\.p([^(]*)i8\(i8([^*]*)\* (.*), i8 (.*), i8 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.memset.p\1i8(i8\2* \3, i8 \4, i8 \5, i1 \6)~g s~call void @llvm\.memset\.p([^(]*)i16\(i8([^*]*)\* (.*), i8 (.*), i16 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.memset.p\1i16(i8\2* \3, i8 \4, i16 \5, i1 \6)~g s~call void @llvm\.memset\.p([^(]*)i32\(i8([^*]*)\* (.*), i8 (.*), i32 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.memset.p\1i32(i8\2* \3, i8 \4, i32 \5, i1 \6)~g s~call void @llvm\.memset\.p([^(]*)i64\(i8([^*]*)\* (.*), i8 (.*), i64 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.memset.p\1i64(i8\2* \3, i8 \4, i64 \5, i1 \6)~g s~call void @llvm\.memset\.p([^(]*)i128\(i8([^*]*)\* (.*), i8 (.*), i128 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.memset.p\1i128(i8\2* \3, i8 \4, i128 \5, i1 \6)~g s~call void @llvm\.memset\.p([^(]*)i8\(i8([^*]*)\* (.*), i8 (.*), i8 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.memset.p\1i8(i8\2* align \6 \3, i8 \4, i8 \5, i1 \7)~g s~call void @llvm\.memset\.p([^(]*)i16\(i8([^*]*)\* (.*), i8 (.*), i16 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.memset.p\1i16(i8\2* align \6 \3, i8 \4, i16 \5, i1 \7)~g s~call void @llvm\.memset\.p([^(]*)i32\(i8([^*]*)\* (.*), i8 (.*), i32 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.memset.p\1i32(i8\2* align \6 \3, i8 \4, i32 \5, i1 \7)~g s~call void @llvm\.memset\.p([^(]*)i64\(i8([^*]*)\* (.*), i8 (.*), i64 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.memset.p\1i64(i8\2* align \6 \3, i8 \4, i64 \5, i1 \7)~g s~call void @llvm\.memset\.p([^(]*)i128\(i8([^*]*)\* (.*), i8 (.*), i128 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.memset.p\1i128(i8\2* align \6 \3, i8 \4, i128 \5, i1 \7)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i8\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i8 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.mem\1.p\2i8(i8\3* \4, i8\5* \6, i8 \7, i1 \8)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i16\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i16 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.mem\1.p\2i16(i8\3* \4, i8\5* \6, i16 \7, i1 \8)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i32\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i32 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.mem\1.p\2i32(i8\3* \4, i8\5* \6, i32 \7, i1 \8)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i64\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i64 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.mem\1.p\2i64(i8\3* \4, i8\5* \6, i64 \7, i1 \8)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i128\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i128 (.*), i32 [01], i1 ([^)]*)\)~call void @llvm.mem\1.p\2i128(i8\3* \4, i8\5* \6, i128 \7, i1 \8)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i8\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i8 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.mem\1.p\2i8(i8\3* align \8 \4, i8\5* align \8 \6, i8 \7, i1 \9)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i16\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i16 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.mem\1.p\2i16(i8\3* align \8 \4, i8\5* align \8 \6, i16 \7, i1 \9)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i32\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i32 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.mem\1.p\2i32(i8\3* align \8 \4, i8\5* align \8 \6, i32 \7, i1 \9)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i64\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i64 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.mem\1.p\2i64(i8\3* align \8 \4, i8\5* align \8 \6, i64 \7, i1 \9)~g s~call void @llvm\.mem(cpy|move)\.p([^(]*)i128\(i8([^*]*)\* (.*), i8([^*]*)\* (.*), i128 (.*), i32 ([0-9]*), i1 ([^)]*)\)~call void @llvm.mem\1.p\2i128(i8\3* align \8 \4, i8\5* align \8 \6, i128 \7, i1 \9)~g The remaining changes in the series will: Step 2) Expand the IRBuilder API to allow creation of memcpy/memmove with differing source and dest alignments. Step 3) Update Clang to use the new IRBuilder API. Step 4) Update Polly to use the new IRBuilder API. Step 5) Update LLVM passes that create memcpy/memmove calls to use the new IRBuilder API, and those that use use MemIntrinsicInst::[get|set]Alignment() to use getDestAlignment() and getSourceAlignment() instead. Step 6) Remove the single-alignment IRBuilder API for memcpy/memmove, and the MemIntrinsicInst::[get|set]Alignment() methods. Reviewers: pete, hfinkel, lhames, reames, bollu Reviewed By: reames Subscribers: niosHD, reames, jholewinski, qcolombet, jfb, sanjoy, arsenm, dschuff, dylanmckay, mehdi_amini, sdardis, nemanjai, david2050, nhaehnle, javed.absar, sbc100, jgravelle-google, eraman, aheejin, kbarton, JDevlieghere, asb, rbar, johnrusso, simoncook, jordy.potman.lists, apazos, sabuasal, llvm-commits Differential Revision: https://reviews.llvm.org/D41675 llvm-svn: 322965
187 lines
7.8 KiB
LLVM
187 lines
7.8 KiB
LLVM
; RUN: opt -instcombine -S < %s | FileCheck %s
|
|
|
|
target datalayout = "e-p:64:64:64-p1:32:32:32-p2:16:16:16-n8:16:32:64"
|
|
|
|
|
|
declare void @llvm.memcpy.p0i8.p0i8.i32(i8*, i8*, i32, i1) nounwind
|
|
declare void @llvm.memcpy.p0i8.p1i8.i32(i8*, i8 addrspace(1)*, i32, i1) nounwind
|
|
declare void @llvm.memcpy.p0i8.p2i8.i32(i8*, i8 addrspace(2)*, i32, i1) nounwind
|
|
|
|
|
|
define i32* @combine_redundant_addrspacecast(i32 addrspace(1)* %x) nounwind {
|
|
; CHECK-LABEL: @combine_redundant_addrspacecast(
|
|
; CHECK: addrspacecast i32 addrspace(1)* %x to i32*
|
|
; CHECK-NEXT: ret
|
|
%y = addrspacecast i32 addrspace(1)* %x to i32 addrspace(3)*
|
|
%z = addrspacecast i32 addrspace(3)* %y to i32*
|
|
ret i32* %z
|
|
}
|
|
|
|
define <4 x i32*> @combine_redundant_addrspacecast_vector(<4 x i32 addrspace(1)*> %x) nounwind {
|
|
; CHECK-LABEL: @combine_redundant_addrspacecast_vector(
|
|
; CHECK: addrspacecast <4 x i32 addrspace(1)*> %x to <4 x i32*>
|
|
; CHECK-NEXT: ret
|
|
%y = addrspacecast <4 x i32 addrspace(1)*> %x to <4 x i32 addrspace(3)*>
|
|
%z = addrspacecast <4 x i32 addrspace(3)*> %y to <4 x i32*>
|
|
ret <4 x i32*> %z
|
|
}
|
|
|
|
define float* @combine_redundant_addrspacecast_types(i32 addrspace(1)* %x) nounwind {
|
|
; CHECK-LABEL: @combine_redundant_addrspacecast_types(
|
|
; CHECK-NEXT: bitcast i32 addrspace(1)* %x to float addrspace(1)*
|
|
; CHECK-NEXT: addrspacecast float addrspace(1)* %1 to float*
|
|
; CHECK-NEXT: ret
|
|
%y = addrspacecast i32 addrspace(1)* %x to i32 addrspace(3)*
|
|
%z = addrspacecast i32 addrspace(3)* %y to float*
|
|
ret float* %z
|
|
}
|
|
|
|
define <4 x float*> @combine_redundant_addrspacecast_types_vector(<4 x i32 addrspace(1)*> %x) nounwind {
|
|
; CHECK-LABEL: @combine_redundant_addrspacecast_types_vector(
|
|
; CHECK-NEXT: bitcast <4 x i32 addrspace(1)*> %x to <4 x float addrspace(1)*>
|
|
; CHECK-NEXT: addrspacecast <4 x float addrspace(1)*> %1 to <4 x float*>
|
|
; CHECK-NEXT: ret
|
|
%y = addrspacecast <4 x i32 addrspace(1)*> %x to <4 x i32 addrspace(3)*>
|
|
%z = addrspacecast <4 x i32 addrspace(3)*> %y to <4 x float*>
|
|
ret <4 x float*> %z
|
|
}
|
|
|
|
define float addrspace(2)* @combine_addrspacecast_bitcast_1(i32 addrspace(1)* %x) nounwind {
|
|
; CHECK-LABEL: @combine_addrspacecast_bitcast_1(
|
|
; CHECK-NEXT: bitcast i32 addrspace(1)* %x to float addrspace(1)*
|
|
; CHECK-NEXT: addrspacecast float addrspace(1)* %1 to float addrspace(2)*
|
|
; CHECK-NEXT: ret
|
|
%y = addrspacecast i32 addrspace(1)* %x to i32 addrspace(2)*
|
|
%z = bitcast i32 addrspace(2)* %y to float addrspace(2)*
|
|
ret float addrspace(2)* %z
|
|
}
|
|
|
|
define i32 addrspace(2)* @combine_addrspacecast_bitcast_2(i32 addrspace(1)* %x) nounwind {
|
|
; CHECK-LABEL: @combine_addrspacecast_bitcast_2(
|
|
; CHECK: addrspacecast i32 addrspace(1)* %x to i32 addrspace(2)*
|
|
; CHECK-NEXT: ret
|
|
%y = addrspacecast i32 addrspace(1)* %x to float addrspace(2)*
|
|
%z = bitcast float addrspace(2)* %y to i32 addrspace(2)*
|
|
ret i32 addrspace(2)* %z
|
|
}
|
|
|
|
define i32 addrspace(2)* @combine_bitcast_addrspacecast_1(i32 addrspace(1)* %x) nounwind {
|
|
; CHECK-LABEL: @combine_bitcast_addrspacecast_1(
|
|
; CHECK: addrspacecast i32 addrspace(1)* %x to i32 addrspace(2)*
|
|
; CHECK-NEXT: ret
|
|
%y = bitcast i32 addrspace(1)* %x to i8 addrspace(1)*
|
|
%z = addrspacecast i8 addrspace(1)* %y to i32 addrspace(2)*
|
|
ret i32 addrspace(2)* %z
|
|
}
|
|
|
|
define float addrspace(2)* @combine_bitcast_addrspacecast_2(i32 addrspace(1)* %x) nounwind {
|
|
; CHECK-LABEL: @combine_bitcast_addrspacecast_2(
|
|
; CHECK: bitcast i32 addrspace(1)* %x to float addrspace(1)*
|
|
; CHECK: addrspacecast float addrspace(1)* %1 to float addrspace(2)*
|
|
; CHECK-NEXT: ret
|
|
%y = bitcast i32 addrspace(1)* %x to i8 addrspace(1)*
|
|
%z = addrspacecast i8 addrspace(1)* %y to float addrspace(2)*
|
|
ret float addrspace(2)* %z
|
|
}
|
|
|
|
define float addrspace(2)* @combine_addrspacecast_types(i32 addrspace(1)* %x) nounwind {
|
|
; CHECK-LABEL: @combine_addrspacecast_types(
|
|
; CHECK-NEXT: bitcast i32 addrspace(1)* %x to float addrspace(1)*
|
|
; CHECK-NEXT: addrspacecast float addrspace(1)* %1 to float addrspace(2)*
|
|
; CHECK-NEXT: ret
|
|
%y = addrspacecast i32 addrspace(1)* %x to float addrspace(2)*
|
|
ret float addrspace(2)* %y
|
|
}
|
|
|
|
define <4 x float addrspace(2)*> @combine_addrspacecast_types_vector(<4 x i32 addrspace(1)*> %x) nounwind {
|
|
; CHECK-LABEL: @combine_addrspacecast_types_vector(
|
|
; CHECK-NEXT: bitcast <4 x i32 addrspace(1)*> %x to <4 x float addrspace(1)*>
|
|
; CHECK-NEXT: addrspacecast <4 x float addrspace(1)*> %1 to <4 x float addrspace(2)*>
|
|
; CHECK-NEXT: ret
|
|
%y = addrspacecast <4 x i32 addrspace(1)*> %x to <4 x float addrspace(2)*>
|
|
ret <4 x float addrspace(2)*> %y
|
|
}
|
|
|
|
define i32 @canonicalize_addrspacecast([16 x i32] addrspace(1)* %arr) {
|
|
; CHECK-LABEL: @canonicalize_addrspacecast(
|
|
; CHECK-NEXT: getelementptr inbounds [16 x i32], [16 x i32] addrspace(1)* %arr, i32 0, i32 0
|
|
; CHECK-NEXT: addrspacecast i32 addrspace(1)* %{{[a-zA-Z0-9]+}} to i32*
|
|
; CHECK-NEXT: load i32, i32*
|
|
; CHECK-NEXT: ret i32
|
|
%p = addrspacecast [16 x i32] addrspace(1)* %arr to i32*
|
|
%v = load i32, i32* %p
|
|
ret i32 %v
|
|
}
|
|
|
|
@const_array = addrspace(2) constant [60 x i8] [i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22,
|
|
i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22,
|
|
i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22,
|
|
i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22,
|
|
i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22 ]
|
|
|
|
declare void @foo(i8*) nounwind
|
|
|
|
; A copy from a constant addrspacecast'ed global
|
|
; CHECK-LABEL: @memcpy_addrspacecast(
|
|
; CHECK-NOT: call void @llvm.memcpy
|
|
define i32 @memcpy_addrspacecast() nounwind {
|
|
entry:
|
|
%alloca = alloca i8, i32 48
|
|
call void @llvm.memcpy.p0i8.p1i8.i32(i8* align 4 %alloca, i8 addrspace(1)* align 4 addrspacecast (i8 addrspace(2)* getelementptr inbounds ([60 x i8], [60 x i8] addrspace(2)* @const_array, i16 0, i16 4) to i8 addrspace(1)*), i32 48, i1 false) nounwind
|
|
br label %loop.body
|
|
|
|
loop.body:
|
|
%i = phi i32 [ 0, %entry ], [ %i.inc, %loop.body ]
|
|
%sum = phi i32 [ 0, %entry ], [ %sum.inc, %loop.body]
|
|
%ptr = getelementptr i8, i8* %alloca, i32 %i
|
|
%load = load i8, i8* %ptr
|
|
%ext = zext i8 %load to i32
|
|
%sum.inc = add i32 %sum, %ext
|
|
%i.inc = add i32 %i, 1
|
|
%cmp = icmp ne i32 %i, 48
|
|
br i1 %cmp, label %loop.body, label %end
|
|
|
|
end:
|
|
ret i32 %sum.inc
|
|
}
|
|
|
|
; CHECK-LABEL: @constant_fold_null(
|
|
; CHECK: i32 addrspace(3)* null to i32 addrspace(4)*
|
|
define void @constant_fold_null() #0 {
|
|
%cast = addrspacecast i32 addrspace(3)* null to i32 addrspace(4)*
|
|
store i32 7, i32 addrspace(4)* %cast
|
|
ret void
|
|
}
|
|
|
|
; CHECK-LABEL: @constant_fold_undef(
|
|
; CHECK: ret i32 addrspace(4)* undef
|
|
define i32 addrspace(4)* @constant_fold_undef() #0 {
|
|
%cast = addrspacecast i32 addrspace(3)* undef to i32 addrspace(4)*
|
|
ret i32 addrspace(4)* %cast
|
|
}
|
|
|
|
; CHECK-LABEL: @constant_fold_null_vector(
|
|
; CHECK: addrspacecast (<4 x i32 addrspace(3)*> zeroinitializer to <4 x i32 addrspace(4)*>)
|
|
define <4 x i32 addrspace(4)*> @constant_fold_null_vector() #0 {
|
|
%cast = addrspacecast <4 x i32 addrspace(3)*> zeroinitializer to <4 x i32 addrspace(4)*>
|
|
ret <4 x i32 addrspace(4)*> %cast
|
|
}
|
|
|
|
; CHECK-LABEL: @constant_fold_inttoptr(
|
|
; CHECK: addrspacecast (i32 addrspace(3)* inttoptr (i32 -1 to i32 addrspace(3)*) to i32 addrspace(4)*)
|
|
define void @constant_fold_inttoptr() #0 {
|
|
%cast = addrspacecast i32 addrspace(3)* inttoptr (i32 -1 to i32 addrspace(3)*) to i32 addrspace(4)*
|
|
store i32 7, i32 addrspace(4)* %cast
|
|
ret void
|
|
}
|
|
|
|
; CHECK-LABEL: @constant_fold_gep_inttoptr(
|
|
; CHECK: addrspacecast (i32 addrspace(3)* inttoptr (i64 1274 to i32 addrspace(3)*) to i32 addrspace(4)*)
|
|
define void @constant_fold_gep_inttoptr() #0 {
|
|
%k = inttoptr i32 1234 to i32 addrspace(3)*
|
|
%gep = getelementptr i32, i32 addrspace(3)* %k, i32 10
|
|
%cast = addrspacecast i32 addrspace(3)* %gep to i32 addrspace(4)*
|
|
store i32 7, i32 addrspace(4)* %cast
|
|
ret void
|
|
}
|