35d3b3430e
One-Shot Bufferize currently does not support loops where a yielded value bufferizes to a buffer that is different from the buffer of the region iter_arg. In such a case, the bufferization fails with an error such as: ``` Yield operand #0 is not equivalent to the corresponding iter bbArg scf.yield %0 : tensor<5xf32> ``` One common reason for non-equivalent buffers is that an op on the path from the region iter_arg to the terminator bufferizes out-of-place. Ops that are analyzed earlier are more likely to bufferize in-place. This commit adds a new heuristic that gives preference to ops that are reachable on the reverse SSA use-def chain from a region terminator and are within the parent region of the terminator. This is expected to work better than the existing heuristics for loops where an iter_arg is written to multiple times within a loop, but only one write is fed into the terminator. Current users of One-Shot Bufferize are not affected by this change. "Bottom-up" is still the default heuristic. Users can switch to the new heuristic manually. This commit also turns the "fuzzer" pass option into a heuristic, cleaning up the code a bit.
62 lines
2.8 KiB
MLIR
62 lines
2.8 KiB
MLIR
// RUN: mlir-opt %s -one-shot-bufferize="bufferize-function-boundaries" -split-input-file | FileCheck %s
|
|
|
|
// Run fuzzer with different seeds.
|
|
// RUN: mlir-opt %s -one-shot-bufferize="test-analysis-only analysis-heuristic=fuzzer analysis-fuzzer-seed=23 bufferize-function-boundaries" -split-input-file -o /dev/null
|
|
// RUN: mlir-opt %s -one-shot-bufferize="test-analysis-only analysis-heuristic=fuzzer analysis-fuzzer-seed=59 bufferize-function-boundaries" -split-input-file -o /dev/null
|
|
// RUN: mlir-opt %s -one-shot-bufferize="test-analysis-only analysis-heuristic=fuzzer analysis-fuzzer-seed=91 bufferize-function-boundaries" -split-input-file -o /dev/null
|
|
|
|
// Test bufferization using memref types that have no layout map.
|
|
// RUN: mlir-opt %s -one-shot-bufferize="unknown-type-conversion=identity-layout-map function-boundary-type-conversion=identity-layout-map bufferize-function-boundaries" -split-input-file -o /dev/null
|
|
|
|
// CHECK-LABEL: func @write_to_select_op_source
|
|
// CHECK-SAME: %[[t1:.*]]: memref<?xf32, strided{{.*}}>, %[[t2:.*]]: memref<?xf32, strided{{.*}}>
|
|
func.func @write_to_select_op_source(
|
|
%t1 : tensor<?xf32> {bufferization.writable = true},
|
|
%t2 : tensor<?xf32> {bufferization.writable = true},
|
|
%c : i1)
|
|
-> (tensor<?xf32>, tensor<?xf32>)
|
|
{
|
|
%cst = arith.constant 0.0 : f32
|
|
%idx = arith.constant 0 : index
|
|
// CHECK: %[[alloc:.*]] = memref.alloc
|
|
// CHECK: memref.copy %[[t1]], %[[alloc]]
|
|
// CHECK: memref.store %{{.*}}, %[[alloc]]
|
|
%w = tensor.insert %cst into %t1[%idx] : tensor<?xf32>
|
|
// CHECK: %[[select:.*]] = arith.select %{{.*}}, %[[t1]], %[[t2]]
|
|
%s = arith.select %c, %t1, %t2 : tensor<?xf32>
|
|
// CHECK: return %[[select]], %[[alloc]]
|
|
return %s, %w : tensor<?xf32>, tensor<?xf32>
|
|
}
|
|
|
|
// -----
|
|
|
|
// Due to the out-of-place bufferization of %t1, buffers with different layout
|
|
// maps are passed to arith.select. A cast must be inserted.
|
|
|
|
// CHECK-LABEL: func @write_after_select_read_one
|
|
// CHECK-SAME: %[[t1:.*]]: memref<?xf32, strided{{.*}}>, %[[t2:.*]]: memref<?xf32, strided{{.*}}>
|
|
func.func @write_after_select_read_one(
|
|
%t1 : tensor<?xf32> {bufferization.writable = true},
|
|
%t2 : tensor<?xf32> {bufferization.writable = true},
|
|
%c : i1)
|
|
-> (f32, tensor<?xf32>)
|
|
{
|
|
%cst = arith.constant 0.0 : f32
|
|
%idx = arith.constant 0 : index
|
|
|
|
// CHECK: %[[alloc:.*]] = memref.alloc
|
|
// CHECK-DAG: %[[casted:.*]] = memref.cast %[[alloc]]
|
|
// CHECK-DAG: memref.copy %[[t1]], %[[alloc]]
|
|
// CHECK: %[[select:.*]] = arith.select %{{.*}}, %[[casted]], %[[t2]]
|
|
%s = arith.select %c, %t1, %t2 : tensor<?xf32>
|
|
|
|
// CHECK: memref.store %{{.*}}, %[[select]]
|
|
%w = tensor.insert %cst into %s[%idx] : tensor<?xf32>
|
|
|
|
// CHECK: %[[f:.*]] = memref.load %[[t1]]
|
|
%f = tensor.extract %t1[%idx] : tensor<?xf32>
|
|
|
|
// CHECK: return %[[f]], %[[select]]
|
|
return %f, %w : f32, tensor<?xf32>
|
|
}
|