a97f62837f
The `dso_local_equivalent` constant is a wrapper for functions that represents a value which is functionally equivalent to the global passed to this. That is, if this accepts a function, calling this constant should have the same effects as calling the function directly. This could be a direct reference to the function, the `@plt` modifier on X86/AArch64, a thunk, or anything that's equivalent to the resolved function as a call target. When lowered, the returned address must have a constant offset at link time from some other symbol defined within the same binary. The address of this value is also insignificant. The name is leveraged from `dso_local` where use of a function or variable is resolved to a symbol in the same linkage unit. In this patch: - Addition of `dso_local_equivalent` and handling it - Update Constant::needsRelocation() to strip constant inbound GEPs and take advantage of `dso_local_equivalent` for relative references This is useful for the [Relative VTables C++ ABI](https://reviews.llvm.org/D72959) which makes vtables readonly. This works by replacing the dynamic relocations for function pointers in them with static relocations that represent the offset between the vtable and virtual functions. If a function is externally defined, `dso_local_equivalent` can be used as a generic wrapper for the function to still allow for this static offset calculation to be done. See [RFC](http://lists.llvm.org/pipermail/llvm-dev/2020-August/144469.html) for more details. Differential Revision: https://reviews.llvm.org/D77248
46 lines
1.7 KiB
LLVM
46 lines
1.7 KiB
LLVM
; RUN: llc -relocation-model=pic -data-sections -o - %s | FileCheck %s
|
|
|
|
target triple = "x86_64-unknown-linux-gnu"
|
|
|
|
@hidden = external hidden global i8
|
|
@default = external global i8
|
|
|
|
; CHECK: .section .rodata.rodata
|
|
; CHECK: rodata:
|
|
; CHECK: .long hidden-rodata
|
|
@rodata = hidden constant i32 trunc (i64 sub (i64 ptrtoint (i8* @hidden to i64), i64 ptrtoint (i32* @rodata to i64)) to i32)
|
|
|
|
; CHECK: .section .data.rel.ro.relro1
|
|
; CHECK: relro1:
|
|
; CHECK: .long default-relro1
|
|
@relro1 = hidden constant i32 trunc (i64 sub (i64 ptrtoint (i8* @default to i64), i64 ptrtoint (i32* @relro1 to i64)) to i32)
|
|
|
|
; CHECK: .section .data.rel.ro.relro2
|
|
; CHECK: relro2:
|
|
; CHECK: .long hidden-relro2
|
|
@relro2 = constant i32 trunc (i64 sub (i64 ptrtoint (i8* @hidden to i64), i64 ptrtoint (i32* @relro2 to i64)) to i32)
|
|
|
|
; CHECK: .section .rodata.cst8
|
|
; CHECK-NEXT: .globl obj
|
|
; CHECK: obj:
|
|
; CHECK: .long 0
|
|
; CHECK: .long (hidden_func-obj)-4
|
|
|
|
declare hidden void @hidden_func()
|
|
|
|
; Ensure that inbound GEPs with constant offsets are also resolved.
|
|
@obj = dso_local unnamed_addr constant { { i32, i32 } } {
|
|
{ i32, i32 } {
|
|
i32 0,
|
|
i32 trunc (i64 sub (i64 ptrtoint (void ()* dso_local_equivalent @hidden_func to i64), i64 ptrtoint (i32* getelementptr inbounds ({ { i32, i32 } }, { { i32, i32 } }* @obj, i32 0, i32 0, i32 1) to i64)) to i32)
|
|
} }, align 4
|
|
|
|
; CHECK: .section .rodata.rodata2
|
|
; CHECK-NEXT: .globl rodata2
|
|
; CHECK: rodata2:
|
|
; CHECK: .long extern_func@PLT-rodata2
|
|
|
|
declare void @extern_func()
|
|
|
|
@rodata2 = dso_local constant i32 trunc (i64 sub (i64 ptrtoint (void ()* dso_local_equivalent @extern_func to i64), i64 ptrtoint (i32* @rodata2 to i64)) to i32)
|