a8aeb651cd
Extend multi-buffering to simplify the affine map created if any of its operands are constants. This avoids downstream problems where more complex affine.apply operations cannot be expanded. Transfer attributes from the old allocation to the new allocation. Reviewed By: ThomasRaoux Differential Revision: https://reviews.llvm.org/D134894
107 lines
5.3 KiB
MLIR
107 lines
5.3 KiB
MLIR
// RUN: mlir-opt %s -allow-unregistered-dialect -test-multi-buffering=multiplier=5 -cse -split-input-file | FileCheck %s
|
|
|
|
// CHECK-DAG: #[[$MAP1:.*]] = affine_map<(d0) -> (((d0 - 1) floordiv 3) mod 5)>
|
|
|
|
// CHECK-LABEL: func @multi_buffer
|
|
func.func @multi_buffer(%a: memref<1024x1024xf32>) {
|
|
// CHECK-DAG: %[[A:.*]] = memref.alloc() {someAttribute} : memref<5x4x128xf32>
|
|
// CHECK-DAG: %[[C1:.*]] = arith.constant 1 : index
|
|
// CHECK-DAG: %[[C3:.*]] = arith.constant 3 : index
|
|
%0 = memref.alloc() {someAttribute} : memref<4x128xf32>
|
|
%c1024 = arith.constant 1024 : index
|
|
%c1 = arith.constant 1 : index
|
|
%c3 = arith.constant 3 : index
|
|
// CHECK: scf.for %[[IV:.*]] = %[[C1]]
|
|
scf.for %arg2 = %c1 to %c1024 step %c3 {
|
|
// CHECK: %[[I:.*]] = affine.apply #[[$MAP1]](%[[IV]])
|
|
// CHECK: %[[SV:.*]] = memref.subview %[[A]][%[[I]], 0, 0] [1, 4, 128] [1, 1, 1] : memref<5x4x128xf32> to memref<4x128xf32, strided<[128, 1], offset: ?>>
|
|
%1 = memref.subview %a[%arg2, 0] [4, 128] [1, 1] :
|
|
memref<1024x1024xf32> to memref<4x128xf32, affine_map<(d0, d1)[s0] -> (d0 * 1024 + s0 + d1)>>
|
|
// CHECK: memref.copy %{{.*}}, %[[SV]] : memref<4x128xf32, #{{.*}}> to memref<4x128xf32, strided<[128, 1], offset: ?>>
|
|
memref.copy %1, %0 : memref<4x128xf32, affine_map<(d0, d1)[s0] -> (d0 * 1024 + s0 + d1)>> to memref<4x128xf32>
|
|
// CHECK: "some_use"(%[[SV]]) : (memref<4x128xf32, strided{{.*}}>) -> ()
|
|
"some_use"(%0) : (memref<4x128xf32>) -> ()
|
|
// CHECK: "some_use"(%[[SV]]) : (memref<4x128xf32, strided{{.*}}>) -> ()
|
|
"some_use"(%0) : (memref<4x128xf32>) -> ()
|
|
}
|
|
return
|
|
}
|
|
|
|
// -----
|
|
|
|
// CHECK-LABEL: func @multi_buffer_affine
|
|
func.func @multi_buffer_affine(%a: memref<1024x1024xf32>) {
|
|
// CHECK-DAG: %[[A:.*]] = memref.alloc() : memref<5x4x128xf32>
|
|
%0 = memref.alloc() : memref<4x128xf32>
|
|
%c1024 = arith.constant 1024 : index
|
|
%c1 = arith.constant 1 : index
|
|
%c3 = arith.constant 3 : index
|
|
// CHECK: affine.for %[[IV:.*]] = 1
|
|
affine.for %arg2 = 1 to 1024 step 3 {
|
|
// CHECK: %[[I:.*]] = affine.apply #[[$MAP1]](%[[IV]])
|
|
// CHECK: %[[SV:.*]] = memref.subview %[[A]][%[[I]], 0, 0] [1, 4, 128] [1, 1, 1] : memref<5x4x128xf32> to memref<4x128xf32, strided<[128, 1], offset: ?>>
|
|
%1 = memref.subview %a[%arg2, 0] [4, 128] [1, 1] :
|
|
memref<1024x1024xf32> to memref<4x128xf32, affine_map<(d0, d1)[s0] -> (d0 * 1024 + s0 + d1)>>
|
|
// CHECK: memref.copy %{{.*}}, %[[SV]] : memref<4x128xf32, #{{.*}}> to memref<4x128xf32, strided<[128, 1], offset: ?>>
|
|
memref.copy %1, %0 : memref<4x128xf32, affine_map<(d0, d1)[s0] -> (d0 * 1024 + s0 + d1)>> to memref<4x128xf32>
|
|
// CHECK: "some_use"(%[[SV]]) : (memref<4x128xf32, strided{{.*}}>) -> ()
|
|
"some_use"(%0) : (memref<4x128xf32>) -> ()
|
|
// CHECK: "some_use"(%[[SV]]) : (memref<4x128xf32, strided{{.*}}>) -> ()
|
|
"some_use"(%0) : (memref<4x128xf32>) -> ()
|
|
}
|
|
return
|
|
}
|
|
|
|
// -----
|
|
|
|
// CHECK-DAG: #[[$MAP1:.*]] = affine_map<(d0) -> (((d0 - 1) floordiv 3) mod 5)>
|
|
|
|
// CHECK-LABEL: func @multi_buffer_subview_use
|
|
func.func @multi_buffer_subview_use(%a: memref<1024x1024xf32>) {
|
|
// CHECK-DAG: %[[A:.*]] = memref.alloc() : memref<5x4x128xf32>
|
|
// CHECK-DAG: %[[C1:.*]] = arith.constant 1 : index
|
|
// CHECK-DAG: %[[C3:.*]] = arith.constant 3 : index
|
|
%0 = memref.alloc() : memref<4x128xf32>
|
|
%c1024 = arith.constant 1024 : index
|
|
%c1 = arith.constant 1 : index
|
|
%c3 = arith.constant 3 : index
|
|
// CHECK: scf.for %[[IV:.*]] = %[[C1]]
|
|
scf.for %arg2 = %c1 to %c1024 step %c3 {
|
|
// CHECK: %[[I:.*]] = affine.apply #[[$MAP1]](%[[IV]])
|
|
// CHECK: %[[SV:.*]] = memref.subview %[[A]][%[[I]], 0, 0] [1, 4, 128] [1, 1, 1] : memref<5x4x128xf32> to memref<4x128xf32, strided<[128, 1], offset: ?>>
|
|
%1 = memref.subview %a[%arg2, 0] [4, 128] [1, 1] :
|
|
memref<1024x1024xf32> to memref<4x128xf32, affine_map<(d0, d1)[s0] -> (d0 * 1024 + s0 + d1)>>
|
|
// CHECK: memref.copy %{{.*}}, %[[SV]] : memref<4x128xf32, #{{.*}}> to memref<4x128xf32, strided<[128, 1], offset: ?>>
|
|
memref.copy %1, %0 : memref<4x128xf32, affine_map<(d0, d1)[s0] -> (d0 * 1024 + s0 + d1)>> to memref<4x128xf32>
|
|
// CHECK: %[[SV1:.*]] = memref.subview %[[SV]][0, 1] [4, 127] [1, 1] : memref<4x128xf32, strided<[128, 1], offset: ?>> to memref<4x127xf32, strided<[128, 1], offset: ?>>
|
|
%s = memref.subview %0[0, 1] [4, 127] [1, 1] :
|
|
memref<4x128xf32> to memref<4x127xf32, affine_map<(d0, d1) -> (d0 * 128 + d1 + 1)>>
|
|
// CHECK: "some_use"(%[[SV1]]) : (memref<4x127xf32, strided<[128, 1], offset: ?>>) -> ()
|
|
"some_use"(%s) : (memref<4x127xf32, affine_map<(d0, d1) -> (d0 * 128 + d1 + 1)>>) -> ()
|
|
// CHECK: "some_use"(%[[SV]]) : (memref<4x128xf32, strided<[128, 1], offset: ?>>) -> ()
|
|
"some_use"(%0) : (memref<4x128xf32>) -> ()
|
|
}
|
|
return
|
|
}
|
|
|
|
// -----
|
|
|
|
// CHECK-LABEL: func @multi_buffer_negative
|
|
func.func @multi_buffer_negative(%a: memref<1024x1024xf32>) {
|
|
// CHECK-NOT: %{{.*}} = memref.alloc() : memref<5x4x128xf32>
|
|
// CHECK: %{{.*}} = memref.alloc() : memref<4x128xf32>
|
|
%0 = memref.alloc() : memref<4x128xf32>
|
|
%c1024 = arith.constant 1024 : index
|
|
%c0 = arith.constant 0 : index
|
|
%c3 = arith.constant 3 : index
|
|
scf.for %arg2 = %c0 to %c1024 step %c3 {
|
|
"blocking_use"(%0) : (memref<4x128xf32>) -> ()
|
|
%1 = memref.subview %a[%arg2, 0] [4, 128] [1, 1] :
|
|
memref<1024x1024xf32> to memref<4x128xf32, affine_map<(d0, d1)[s0] -> (d0 * 1024 + s0 + d1)>>
|
|
memref.copy %1, %0 : memref<4x128xf32, affine_map<(d0, d1)[s0] -> (d0 * 1024 + s0 + d1)>> to memref<4x128xf32>
|
|
"some_use"(%0) : (memref<4x128xf32>) -> ()
|
|
}
|
|
return
|
|
}
|
|
|